Подсветка потока ошибок в zsh

$ autoload -U promptinit
$ promptinit

prompt -l           # показать доступные темы
prompt -p <тема>    # просмотреть preview темы
prompt -h <тема>    # помощь по теме
prompt -s <тема>    # установить тему
prompt_<тема>_setup # настройка темы

source ~/.zsh_prompt

setopt prompt_subst
setopt prompt_bang
 
# устанавливаем настройки уставновки заголовков окна в различных терминалах
case $TERM in
    *xterm*|rxvt*|(dt|k|E)term*)
        preexec () { print -Pn "\e]0;%n@%m<%~ [$2]\a" }
        prompt_term_precmd() { print -Pn "\e]0;%n@%m: %~\a" }
 
    ;;
    screen*)
        preexec () {
            print -Pn "\e]0;$2\a"
            print -Pn "\ek%~ <$1>\e\\" # && print -Pn "\e]0;(screen)%n@%m<%~ [$1]\a" 
        }
 
        prompt_term_precmd() {
            #print -Pn "\e]2;%~\a" 
            print -Pn "\ek<%~>\e\\" # && print -Pn "\e]0;(screen)%n@%m: %~\a"
        }
    ;;
    *) prompt_term_precmd() {} ;;
esac
 
# часики справа
RPROMPT=$'%b%F{cyan}%T%f'
 
# что бы часики тикали сами, а не только после запуска команды
schedprompt() {
  emulate -L zsh
  zmodload -i zsh/sched
 
  # Remove existing event, so that multiple calls to
  # "schedprompt" work OK.  (You could put one in precmd to push
  # the timer 30 seconds into the future, for example.)
  integer i=${"${(@)zsh_scheduled_events#*:*:}"[(I)schedprompt]}
  (( i )) && sched -$i
 
  # Test that zle is running before calling the widget (recommended
  # to avoid error messages).
  # Otherwise it updates on entry to zle, so there's no loss.
  zle && zle reset-prompt
 
  # This ensures we're not too far off the start of the minute
  sched +30 schedprompt
}
 
 
# если шел запущен через ssh клиент, выводить имя пользователя другим цветом
if [[ -n "$SSH_CLIENT" ]]; then
    HOSTCOLOR=%B%F{blue}
else
    HOSTCOLOR=%b%F{yellow}
fi
 
# фунция для отлавливания кода ошибки последней запущеной команды
prompt_precmd ()
{
    setopt noxtrace localoptions
    local exitstatus=$1
    [[ $exitstatus -ge 128 ]] && psvar[1]=" $signals[$exitstatus-127]" ||
        psvar[1]=""
 
    [[ -o interactive ]] && jobs -l
 
}
 
# эта фунция запускается после каждой введённой команды
precmd() {
    local exitstatus=$?
    [[ -t 1 ]] || return    # not batch mode
 
    prompt_precmd $exitstatus;
    prompt_term_precmd;
}
 
show_prompt {}
{
    p_rc="%(?..<%?%1v>)"
 
    PROMPT="\
%(!.%{%B%F{yellow}%}%n%{%b%F{red}%}@.)\
%{$HOSTCOLOR%}%m\
%{%b%F{white}%}!$p_shlvlhist%{%b%F{cyan}%}%l\
%{%(?.%b%F{red}.%B%F{red})%}<$p_rc\
%{%B%F{green}%}%~/%f\
"
 
    PROMPT2='%(4_.\.)%3_> %E'
 
}
 
# draw prompt first time
show_prompt
schedprompt